📌  相关文章
📜  Fortran-模块

📅  最后修改于: 2020-11-04 06:20:37             🧑  作者: Mango

模块就像一个包，如果您要编写一个很大的程序，则可以保留函数和子例程，或者可以在多个程序中使用函数或子例程。

模块为您提供了一种在多个文件之间拆分程序的方法。

模块用于-

  • 打包子程序，数据和接口块。

  • 定义可以被多个例程使用的全局数据。

  • 声明可以在您选择的任何例程中使用的变量。

  • 完全导入模块以供使用，然后将其导入另一个程序或子例程。

模块的语法

一个模块由两部分组成-

  • 声明声明的规范部分
  • 一个包含子例程和函数定义的部分

模块的一般形式是-

module name     
   [statement declarations]  
   [contains [subroutine and function definitions] ] 
end module [name]

在程序中使用模块

您可以通过use语句将模块合并到程序或子例程中-

use name

请注意

  • 您可以根据需要添加任意数量的模块，每个模块都位于单独的文件中并分别编译。

  • 一个模块可以在各种不同的程序中使用。

  • 一个模块可以在同一程序中多次使用。

  • 在模块规范部分中声明的变量是模块的全局变量。

  • 在模块中声明的变量将成为使用该模块的任何程序或例程中的全局变量。

  • use语句可以出现在主程序或使用在特定模块中声明的例程或变量的任何其他子例程或模块中。

例

以下示例演示了概念-

现场演示
module constants  
implicit none 

   real, parameter :: pi = 3.1415926536  
   real, parameter :: e = 2.7182818285 
   
contains      
   subroutine show_consts()          
      print*, "Pi = ", pi          
      print*,  "e = ", e     
   end subroutine show_consts 
   
end module constants 


program module_example     
use constants      
implicit none     

   real :: x, ePowerx, area, radius 
   x = 2.0
   radius = 7.0
   ePowerx = e ** x
   area = pi * radius**2     
   
   call show_consts() 
   
   print*, "e raised to the power of 2.0 = ", ePowerx
   print*, "Area of a circle with radius 7.0 = ", area  
   
end program module_example

当您编译并执行上述程序时，它将产生以下结果-

Pi = 3.14159274    
e =  2.71828175    
e raised to the power of 2.0 = 7.38905573    
Area of a circle with radius 7.0 = 153.938049

模块中变量和子例程的可访问性

默认情况下，通过use语句，模块中的所有变量和子例程可用于使用模块代码的程序。

但是，您可以使用private和public属性控制模块代码的可访问性。当您将某些变量或子例程声明为私有时，该变量或子例程在模块外部不可用。

例

以下示例说明了概念-

在前面的示例中，我们有两个模块变量e和pi。让我们将它们设为私有并观察输出-

现场演示
module constants  
implicit none 

   real, parameter,private :: pi = 3.1415926536  
   real, parameter, private :: e = 2.7182818285 
   
contains      
   subroutine show_consts()          
      print*, "Pi = ", pi          
      print*, "e = ", e     
   end subroutine show_consts 
   
end module constants 


program module_example     
use constants      
implicit none     

   real :: x, ePowerx, area, radius 
   x = 2.0
   radius = 7.0
   ePowerx = e ** x
   area = pi * radius**2     
   
   call show_consts() 
   
   print*, "e raised to the power of 2.0 = ", ePowerx
   print*, "Area of a circle with radius 7.0 = ", area  
   
end program module_example

当您编译并执行上述程序时，它给出以下错误消息-

ePowerx = e ** x
   1
Error: Symbol 'e' at (1) has no IMPLICIT type
main.f95:19.13:

   area = pi * radius**2     
   1
Error: Symbol 'pi' at (1) has no IMPLICIT type

由于e和pi都被声明为私有，因此程序module_example无法再访问这些变量。

但是，其他模块子例程可以访问它们-

现场演示
module constants  
implicit none 

   real, parameter,private :: pi = 3.1415926536  
   real, parameter, private :: e = 2.7182818285 
   
contains      
   subroutine show_consts()          
      print*, "Pi = ", pi          
      print*, "e = ", e     
   end subroutine show_consts 
   
   function ePowerx(x)result(ePx) 
   implicit none
      real::x
      real::ePx
      ePx = e ** x
   end function ePowerx
    
   function areaCircle(r)result(a)  
   implicit none
      real::r
      real::a
      a = pi * r**2  
   end function areaCircle
    
end module constants 


program module_example     
use constants      
implicit none     

   call show_consts() 
   
   Print*, "e raised to the power of 2.0 = ", ePowerx(2.0)
   print*, "Area of a circle with radius 7.0 = ", areaCircle(7.0)  
   
end program module_example

当您编译并执行上述程序时，它将产生以下结果-

Pi = 3.14159274    
e = 2.71828175    
e raised to the power of 2.0 = 7.38905573    
Area of a circle with radius 7.0 = 153.938049